{
  description = "iFSR Manual";

  outputs = { self, nixpkgs }:
    let
      supportedSystems = [ "x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin" ];
      forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
      pkgs = forAllSystems (system: nixpkgs.legacyPackages.${system});
    in
    {

      overlays.default = (_final: prev: {
        inherit (self.packages.${prev.system}) ese-manual;
      });

      nixosModules.default = {
        imports = [ ./module.nix ];

        nixpkgs.overlays = [ self.overlays.default ];
      };

      packages = forAllSystems (system: rec {

        default = ese-manual;

        ese-manual = pkgs.${system}.stdenvNoCC.mkDerivation {
          name = "ese-manual";
          src = ./.;
          buildInputs = with pkgs.${system}.python3Packages; [
            mkdocs-material
          ];
          # phases = [ "unpackPhase" "installPhase" ];
          buildPhase = ''
            mkdocs build
          '';
          installPhase = ''
            mkdir -p $out
            cp -r site/* $out
          '';
        };
      });
    };
}